mirror of
https://github.com/fergalmoran/ladybird.git
synced 2026-02-14 11:45:04 +00:00
a0dd6ec6b1
At any one given time, there can be an abitrary number of USB drivers in the system. The way driver mapping works (i.e, a device is inserted, and a potentially matching driver is probed) requires us to have instantiated driver objects _before_ a device is inserted. This leaves us with a slight "chicken and egg" problem. We cannot call the probe function before the driver is initialised, but we need to know _what_ driver to initialise. This section is designed to store pointers to functions that are called during the last stage of the early `_init` sequence in the Kernel. The accompanying macro in `USBDriver` emits a symbol, based on the driver name, into this table that is then automatically called. This way, we enforce a "common" driver model; driver developers are not only required to write their driver and inherit from `USB::Driver`, but are also required to have a free floating init function that registers their driver with the USB Core.
105 lines
2.0 KiB
Plaintext
105 lines
2.0 KiB
Plaintext
/*
|
|
* Copyright (c) 2023, Sönke Holz <sholz830@gmail.com>
|
|
*
|
|
* SPDX-License-Identifier: BSD-2-Clause
|
|
*/
|
|
|
|
ENTRY(start)
|
|
|
|
KERNEL_MAPPING_BASE = 0x2000000000;
|
|
|
|
/* TODO: Add FLAGS to the program headers */
|
|
PHDRS
|
|
{
|
|
text PT_LOAD ;
|
|
data PT_LOAD ;
|
|
ksyms PT_LOAD ;
|
|
bss PT_LOAD ;
|
|
}
|
|
|
|
SECTIONS
|
|
{
|
|
. = KERNEL_MAPPING_BASE;
|
|
|
|
start_of_kernel_image = .;
|
|
|
|
.text ALIGN(4K) :
|
|
{
|
|
start_of_kernel_text = .;
|
|
*(.text.first)
|
|
|
|
start_of_safemem_text = .;
|
|
KEEP(*(.text.safemem))
|
|
end_of_safemem_text = .;
|
|
start_of_safemem_atomic_text = .;
|
|
KEEP(*(.text.safemem.atomic))
|
|
end_of_safemem_atomic_text = .;
|
|
|
|
*(.text*)
|
|
end_of_kernel_text = .;
|
|
} :text
|
|
|
|
.driver_init ALIGN(4K) : AT (ADDR(.driver_init))
|
|
{
|
|
driver_init_table_start = .;
|
|
*(.driver_init)
|
|
driver_init_table_end = .;
|
|
} :text
|
|
|
|
.rodata ALIGN(4K) :
|
|
{
|
|
start_heap_ctors = .;
|
|
*libkernel_heap.a:*(.init_array)
|
|
end_heap_ctors = .;
|
|
|
|
start_ctors = .;
|
|
*(.init_array)
|
|
end_ctors = .;
|
|
|
|
*(.rodata*)
|
|
} :data
|
|
|
|
.data ALIGN(4K) :
|
|
{
|
|
start_of_kernel_data = .;
|
|
*(.data*)
|
|
end_of_kernel_data = .;
|
|
} :data
|
|
|
|
.ksyms ALIGN(4K) :
|
|
{
|
|
start_of_kernel_ksyms = .;
|
|
*(.kernel_symbols)
|
|
end_of_kernel_ksyms = .;
|
|
} :ksyms
|
|
|
|
.bss ALIGN(4K) (NOLOAD) :
|
|
{
|
|
start_of_bss = .;
|
|
*(.bss)
|
|
end_of_bss = .;
|
|
|
|
. = ALIGN(4K);
|
|
*(.heap)
|
|
} :bss
|
|
|
|
/*
|
|
FIXME: 8MB is enough space for all of the tables required to identity map
|
|
physical memory. 8M is wasteful, so this should be properly calculated.
|
|
*/
|
|
|
|
/* FIXME: Placeholder to satisfy linker */
|
|
start_of_unmap_after_init = .;
|
|
end_of_unmap_after_init = .;
|
|
start_of_ro_after_init = .;
|
|
end_of_ro_after_init = .;
|
|
|
|
. = ALIGN(4K);
|
|
page_tables_phys_start = .;
|
|
|
|
. += 8M;
|
|
page_tables_phys_end = .;
|
|
|
|
end_of_kernel_image = .;
|
|
}
|